/* Chapter 8 
++++++++++++++++++++++++++++++++++++++++++++
page 159  Program 8.1  */ 


data resplong ;
  infile 'c:\book\RepeatedMeasure\longresp.txt' missover;
  input no centre subject visit treatment status gender age;
  if visit=0 then post=0; else post=1;
  run;


ods graphics on;

/* Model I */
proc glimmix data=resplong method=quad (qpoints=15)
   plots=studentpanel( conditional blup) 
   plots=boxplot( conditional subject);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment visit treatment*visit 
                                                        / d=bin link=logit s cl ;
   random intercept /  subject= subject g gcorr ;
run;



/* Model IIa */
proc glimmix data=resplong method=quad (qpoints=15)
   plots=studentpanel( conditional blup) 
   plots=boxplot( conditional subject);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment visit treatment*visit 
                                                        / d=bin link=logit s cl ;
   random intercept post / type=simple  subject= subject g gcorr ;
run;



/* Model IIb */
proc glimmix data=resplong method=quad (qpoints=15)
   plots=studentpanel( conditional blup) 
   plots=boxplot( conditional subject);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment visit treatment*visit 
                                                        / d=bin link=logit s cl ;
   random intercept post / type=un  subject= subject g gcorr ;
run;



/*
++++++++++++++++++++++++++++++++++++++++++++
page 163  Program 8.2  */ 


proc glimmix data=resplong method=quad (qpoints=15) ;
   class subject centre visit/ref=first  ;
   model status (event="1")  =  treatment visit treatment*visit 
                                                        / d=bin link=logit s cl ;
run;



/*
++++++++++++++++++++++++++++++++++++++++++++
page 170  programs 8.3 ( Model IV ) */

/* Model IV */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit  / ref=first  ;
   model status (event="1")  = centre gender age  treatment  post treatment*post 
                                                        / d=bin link=logit s cl ;
   random intercept /  subject= subject g gcorr ;
run ;



/* Model Va */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit  / ref=first  ;
   model status (event="1")  = centre gender age  treatment  post treatment*post 
                                                        / d=bin link=logit s cl ;
   random intercept post / type=simple  subject= subject g gcorr ;
run ;


/* Model Vb */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit  / ref=first  ;
   model status (event="1")  = centre gender age  treatment  post treatment*post 
                                                        / d=bin link=logit s cl ;
   random intercept post / type=un  subject= subject g gcorr ;
run ;



/*
++++++++++++++++++++++++++++++++++++++++++++
page 173  Program 8.4 ( Model VI ) */


data resplong ;
  infile 'c:\book\RepeatedMeasure\longresp.txt' missover;
  input no centre subject visit treatment status gender age;
  if visit=0 then post=0; else post=1;
  xvisit=visit;
  run;


/* Model VI */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment xvisit treatment*xvisit 
                                                        / d=bin link=logit s cl ;
   random intercept /  subject= subject g gcorr ;
run;

 

/* Model VIIa */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment xvisit treatment*xvisit 
                                                        / d=bin link=logit s cl ;
   random intercept xvisit / type=simple  subject= subject g gcorr ;
run;



/* Model VIIb */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment xvisit treatment*xvisit 
                                                        / d=bin link=logit s cl ;
   random intercept xvisit / type=un  subject= subject g gcorr ;
run;




/*
++++++++++++++++++++++++++++++++++++++++++++
page 176  Programs 8.5  */


data resplong ;
  infile 'c:\book\RepeatedMeasure\longresp.txt' missover;
  input no centre subject visit treatment status gender age;
  if visit=0 then post=0; else post=1;
  xvisit=visit;
  xvisit2=xvisit*xvisit; 
  run;


/* Model VIQ */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment xvisit xvisit2 
                                      treatment*xvisit  treatment*xvisit2 
                                                        / d=bin link=logit s cl ;
   random intercept /  subject= subject g gcorr ;
run;


/* Model VIIQ-1 */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment xvisit xvisit2 
                                      treatment*xvisit  treatment*xvisit2 
                                                        / d=bin link=logit s cl ;
   random intercept xvisit/ type=simple  subject= subject g gcorr ;
run;


/* Model VIIQ-2 */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment xvisit xvisit2 
                                      treatment*xvisit  treatment*xvisit2 
                                                        / d=bin link=logit s cl ;
   random intercept xvisit / type=un  subject= subject g gcorr ;
run;


/* Model VIIQ-3 */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age treatment xvisit xvisit2 
                                      treatment*xvisit  treatment*xvisit2 
                                                        / d=bin link=logit s cl ;
   random intercept xvisit xvisit2 / type=simple  subject= subject g gcorr ;
run;


/*
++++++++++++++++++++++++++++++++++++++++++++
page 182  Program 8.6  */


data resplong2 ;
  infile 'c:\book\RepeatedMeasure\longrespbase.txt' missover;
  input no centre subject visit treatment status gender age base;
  run;


/* Model VIII  */
proc glimmix data=resplong2 method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age base  treatment visit treatment*visit
                                                        / d=bin link=logit s cl ;
   random intercept /  subject= subject g gcorr ;
   estimate 'treatment at 1m'
      treatment 1 -1 treatment*visit  0 0 0 1 /divisor=1 cl alpha=0.05;
   estimate 'treatment at 2m'
      treatment 1 -1 treatment*visit  1 0 0 0 /divisor=1 cl alpha=0.05;
   estimate 'treatment at 3m'
      treatment 1 -1 treatment*visit  0 1 0 0 /divisor=1 cl alpha=0.05;
   estimate 'treatment at 4m'
      treatment 1 -1 treatment*visit  0 0 1 0 /divisor=1 cl alpha=0.05;
  run ;


/* Model IX  */
proc glimmix data=resplong2 method=quad (qpoints=15);
   class subject centre visit/ref=first  ;
   model status (event="1")  = centre gender age base treatment 
                                                        / d=bin link=logit s cl ;
   random intercept /  subject= subject g gcorr ;
  run ;



/*
++++++++++++++++++++++++++++++++++++++++++++
page 187  Program 8.7  */

data resplong ;
  infile 'c:\book\RepeatedMeasure\longgastro.txt' missover;
  input no subject treatment visit status ;
  if visit<=0 then post=0; else post=1;
  run;


/* Model IV */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject visit  / ref=first  ;
   model status (event="1")  = treatment  post treatment*post 
                          /d=bin link=logit s cl ;
   random intercept /subject= subject g gcorr ;
run ;


/* Model Va */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject visit  / ref=first  ;
   model status (event="1")  = treatment  post treatment*post 
                          /d=bin link=logit s cl ;
   random intercept post / type=simple subject= subject g gcorr ;
run ;


/* Model Vb */
proc glimmix data=resplong method=quad (qpoints=15);
   class subject visit  / ref=first  ;
   model status (event="1")  = treatment  post treatment*post 
                          /d=bin link=logit s cl ;
   random intercept post / type=un subject= subject g gcorr ;
run ;